10 'STAR TREK BY AL WALLACE
20 'REQUIRES 48K
50 CM=1:GOSUB3100:PRINT"INITIALIZING...";:PRINT".";:IFCM<5,DEFINTA-Z:CLEAR365:RANDOM:PRINT".";
60 GOSUB4700:DIMG(7,7),S(7,7),XV(51),YV(51),BT(7,7):PRINT".";
70 'INIT STRINGS
80 GOSUB8600:PRINT".";
90 'SET ALL GYRS TO GREEN
100 GOSUB6600:PRINT".";
130 'SETUP HOSTILE BASE
140 IFCM<5,XH=RND(7):YH=RND(7)
145 IFCM=6,XH=RND*6+1:YH=RND*6+1
148 G(XH,YH)=1051122:PRINT"."
150 'SETUP E'S START SECTOR
160 IFCM<5,X=RND(7):Y=RND(7):IFX=XHANDY=YH,150
165 IFCM=6,X=INT(RND(1)+1):Y=INT(RND(1)*7+1):IFX=XHANDY=YH,150
170 'DRAW STAR TREK
180 GOSUB14000
190 'LIST CREDITS
200 GOSUB10000
210 'CONTACT US
220 GOSUB4600
230 'YOU MUST
240 GOSUB10300
242 'SHOW ABBREVS
245 GOSUB6700:WT=1711:GOSUB31350
250 'GET COORD SYS
260 GOSUB3700:GOSUB4500:GOSUB31350
270 'SETUP WHS
280 GOSUB1500
290 'RANDOMLY DEFINE SECTORS
300 GOSUB8800
310 'MAKE S VAC
320 GOSUB1100
330 'GET S DATA
340 GOSUB8900
350 'CODE S
360 GOSUB10200
370 'SKIP SD UPD
380 GOTO420
390 'START TURN
400 'UPD SD & DEC E FOR USE OF SH
410 SD=SD+.5:E=E-4*SH:PRINT:IFCM<5,SD=SD+RND(.5)
414 IFCM=6,SD=SD+RND*.5
420 'SET CO$
430 GOSUB6500
440 SU=46-INT(SD-RS)
460 GOSUB3100:PRINT@326,USING"STARDATE:  ##.###";SD
470 WT=89:GOSUB2700
480 'RUNNING OUT OF?
490 GOSUB2400
500 '1ST HALF OF MAIN
510 GOSUB18000:PRINT@704,;:CE$=PW$:GOSUB7900:GOSUB9900:PRINT@704,S0$;:PRINT@640,STRING$(64,140);
520 '2ND HALF OF MAIN SCR
540 GOSUB10500:WT=851:GOSUB2700
550 'SC SHORTCUT
560 IFZ$="c"ORZ$="C",WT=181:GOSUB1700:GOTO670
570 'PROCESS BAD INPUT
580 IFZ=9OR(Z=0AND(Z$<>""ANDZ$<>"0"ANDZ$<>"c"ANDZ$<>"C")),540
590 'SKIP TURN
600 IFZ$="0",GOSUB3100:PRINT"SKIPPING TURN":WT=221:GOTO670
610 'OOT
620 IFQQ=WT+1AND(Z$=""OR(Z$<>""AND(Z=0ORZ=9))),OT=OT+1:IFOT<3,GOSUB3100:PRINT"YOU RAN OUT OF TIME TO MAKE A   DECISION";:WT=221:IFOT=1,PRINT"!":GOTO670ELSEPRINT".":PRINT"THIS IS YOUR LAST WARNING!":GOTO670ELSE860
640 'NAV, CMP, SH-SC, W, CHT, AB, STS, COORD SYS
650 GOSUB3700:WT=251:ONZGOSUB4800,5600,6100,9000,15000,7000,11200,4500
670 GOSUB31350
680 'SH INT RPT
690 GOSUB3500:IFEV=0,840
700 'THEIR TURN
710 GOSUB3100:PRINT@324,"* ENEMY ACTIVITY DETECTED *":WT=85:GOSUB2700
720 GOSUB3100:PRINTUSING"(#";EV;:PRINT") HOSTILE SHIP";:IFEV<>1,PRINT"S";
730 PRINT" MOVING":PRINTGF"FERENGI"GK"KLINGON"GR"ROMULAN":GOSUB8500:IFRND(100)<17,EA=0ELSEEA=RND(EV)
750 'ENS E DSNT NOT GET ATKD TWICE IN A ROW
755 IFHA=0ANDEA=0,EA=RND(EV)
757 HA=EA
760 'E TAKIN FIRE
770 GOSUB11300
780 'IF NO SC, CREW INJ-KLD
790 IFSC=0,GOSUB5100
800 'SH
810 GOSUB8400
820 'SC INT
830 GOSUB4100:GOSUB31350
840 'RESET GYRS
850 GOSUB8700
860 'GET FAILURE/SUCCESS/NEITHER
870 GOSUB3300
880 'END OR START OF TURN
890 IFA1$="NEITHER",390
920 'FAILURE-SUCCESS?
930 IFA1$="FAILURE",AD$="FAILED":A2=45ELSEAD$="SAVED":A2=43
950 GOSUB3700:PRINTSTRING$(64,A2)"YOU HAVE "AD$" THE FEDERATION!":OV = 1
960 'INEPT & LOC
970 IFA1$="FAILURE",GOSUB3400:PRINT"YOU WERE IN SECTOR ";:Q=X:Z=Y:GOSUB7200:GOSUB5800
980 PRINTSTRING$(64,A2);
990 'HOSTILE ALIEN BASE?
1000 GOSUB11000:PRINTSTRING$(64,A2):WT=481:GOSUB31350:GOSUB8100:WT=541:GOSUB31350
1010 'STATS
1020 GOSUB3700:GOSUB11200
1030 'PLAY AGAIN?
1040 GOTO7100
1100 'SUB MAKE.S.VAC
1199 FORQ=1TO7:FORZ=1TO7:S(Q,Z)=46:PRINT".";:NEXTZ,Q:RETURN
1200 'SUB WHITE OUT
1299 GOSUB3700:FORI=1TO4:PRINTSTRING$(255,191);:NEXT:RETURN
1300 'SUB SET.SH.ST
1310 IFSH<81,IFSH<21,SH$=R$ELSESH$=Y$ELSESH$=G$
1399 RETURN
1400 'SUB UPD.SC.&.TS
1410 SC=SC+DC:IFDC>0,TS=TS-1:SS(WC)=1ELSESS(WC)=0
1420 IFDC>0ANDTS=0,PRINT:PRINT:PRINT"THAT WAS THE LAST OF OUR SPACE":PRINT"CHAFF"
1499 RETURN
1500 'SUB SETUP.W
1510 GOSUB3100:PRINT"THE SECTORS OF THE GALAXY ARE   NOW BEING CREATED..."
1520 'WM HS = 26-40.  SET B&ES
1530 NW=(12+RND(8))*2:DIMW(NW):PRINT:PRINT"THERE ARE"NW"WORM HOLES":PRINT:PRINT"CHECKING WORM HOLES";
1540 'LOOP THRU WM HS AND RESET DUPS
1550 GOSUB4000:W(1)=W9:FORW1=2TONW
1560 PRINT".";:GOSUB4000:W(W1)=W9
1580 FORW0=1TOW1-1:IFW(W1)=W(W0),W(W1)=0:W0=W1-1
1590 NEXT:IFW(W1)=0,1560
1600 NEXT:PRINT:PRINT
1610 'PR LIST OF WM HS
1620 CE$="WORM HOLES IN ":IFRD,CEW$=CE$+CC$ELSECE$=CE$+GC$
1622 GOSUB7900:PRINT:PRINT"       ";:FORW1=1TONW:WX=INT(W(W1)/10):WY=W(W1)-10*WX:PRINTUSING"## ";W1;:Q=WX:Z=WY:GOSUB7300
1625 IFW1=24,PRINTCHR$(8)"...":PRINT
1630 IFW1<>24ANDW1/2=INT(W1/2),PRINT:PRINT"       ";
1640 IFW1=24,WT=2501:GOSUB31350:GOSUB3100:CE$="WORM HOLES (CONT.) IN ":IFRD,CE$=CE$+"CARTESIAN"ELSECE$=CE$+"GAME"
1642 IFW1=24,GOSUB7900:CE$="COORDS":GOSUB7900:PRINT:PRINT"    ...";
1650 IFW1=NW,PRINT:WT=WT*(NW-24)/16:GOSUB31350:GOSUB3100:PRINT"CONTINUING TO CREATE YOUR GALAXY";
1699 G(WX,WY)=G(WX,WY)+100000:NEXT:RETURN
1700 'SUB DEP.DE-A.SC
1710 GOSUB3100:IFTS>0ANDSC<EV,DC=1ELSEDC=DC*-1
1720 IFDC>0ANDEV=0,GOSUB2300:PRINT@192,"IT WOULD BE A WASTE OF TIME AND":PRINT"ENERGY TO DEPLOY SPACE CHAFF":WT=131:RETURN
1730 IFDC>0ANDTS=0,GOSUB3900:RETURN
1740 IFDC>0,ET=46:NV=67ELSEET=67:NV=46
1750 IFDC>0ANDTS>0ANDTS<8,PRINT"SPACE CHAFF IS DANGEROUSLY LOW!":GOSUB31350
1760 '-1,-1
1770 PRINT".";:IF(A-1)>0AND(B-1)>0,IFS(A-1,B-1)=ET,S(A-1,B-1)=NV:WC=1:GOSUB1400:IFTS=0,RETURN
1780 '-1,0
1790 PRINT".";:IF(A-1)>0,IFS(A-1,B)=ET,S(A-1,B)=NV:WC=2:GOSUB1400:IFTS=0,RETURN
1800 '-1,+1
1810 PRINT".";:IF(A-1)>0AND(B+1)<8,IFS(A-1,B+1)=ET,S(A-1,B+1)=NV:WC=3:GOSUB1400:IFTS=0,RETURN
1820 '+1,-1
1830 PRINT".";:IF(A+1)<8AND(B-1)>0,IFS(A+1,B-1)=ET,S(A+1,B-1)=NV:WC=4:GOSUB1400:IFTS=0,RETURN
1840 '+1,0
1850 PRINT".";:IF(A+1)<8,IFS(A+1,B)=ET,S(A+1,B)=NV:WC=5:GOSUB1400:IFTS=0,RETURN
1860 '+1,+1
1870 PRINT".";:IF(A+1)<8AND(B+1)<8,IFS(A+1,B+1)=ET,S(A+1,B+1)=NV:WC=6:GOSUB1400:IFTS=0,RETURN
1880 '0,-1
1890 PRINT".";:IF(B-1)>0,IFS(A,B-1)=ET,S(A,B-1)=NV:WC=7:GOSUB1400:IFTS=0,RETURN
1900 '0,+1
1910 PRINT".":IF(B+1)<8,IFS(A,B+1)=ET,S(A,B+1)=NV:WC=8:GOSUB1400:IFTS=0,RETURN
1920 GOSUB3100:PRINTS9$"DE";:IFDC>0,PRINT"PLOYED+"ELSEPRINT"-ACTIVATED-"
1999 WT=81:RETURN
2000 'SUB VE
2010 EN=0:FORI=1TO7:FORJ=1TO7:IFS(I,J)=70ORS(I,J)=75ORS(I,J)=82,EN=EN+1:VE(EN)=I+10*J
2099 NEXTJ,I:RETURN
2100 'SUB MEGA-PHASR
2110 PRINT"CONTINUE"WI$P1$" (DEFAULT = YES OR NO)";:INPUTMP$:IFMP$=""ORMP$="y"ORMP$="Y"ORMP$="yes"ORMP$="YES",GOTO2120ELSEPRINT"NO":RETURN
2120 E=E-5000:PRINTP1$" AWAY!":PRINT"ENERGY USED = 5000":EV=0:IFRD,FORW=1TO7:FORV=1TO7ELSEFORV=1TO7:FORW=1TO7
2130 IFRD,SW=S(V,W):Z=YELSESW=S(W,V):Z=8-Y
2140 IFSW=42ORSW=46ORSW=69ORSW=87,2199
2150 IFSW=83,G(X,Z)=G(X,Z)+10000:S1=1:GOSUB7500:PRINT"OOPS, THAT WAS A SUPPLY PLANET"
2160 IFSW<>66ANDSW<>72,S1=0:GOSUB7500
2170 IFSW=66,S1=1:GOSUB7500:PRINT"OOPS, THAT WAS A FEDERATION STARBASE":G(X,Z)=G(X,Z)+10000
2180 IFSW=72,S1=0:GOSUB7500:PRINT"HURRAY, THAT WAS THE HOSTILE ENEMY BASE":XH=-XH
2199 IFRD,NEXTV,W:RETURNELSENEXTW,V:RETURN
2200 'SUB ON-OFF.SH.INT.RPT
2210 GOSUB3100:PRINT"SHIELD INTENTION REPORT":IFSR=0,SR=1:PRINT"ENABLED!+"ELSESR=0:PRINT"DISABLED!-"
2299 WT=101:RETURN
2300 'SUB S.IS.CLR
2399 GOSUB3100:PRINT"SECTOR IS CLEAR!":PRINT"THERE IS NOTHING TO SHOOT AT!":RETURN
2400 'SUB RUNNING.OUT.OF?
2410 G3=0:GOSUB3700:WT=101:IFE<=5000,IFE<=0,860ELSEPRINT"YOU ARE RUNNING OUT OF ENERGY!":PRINT"YOU ONLY HAVE"E"UNITS OF ENERGY LEFT":G3=1
2420 IFSU<=10,PRINT"YOU ARE RUNNING OUT OF SUPPLIES!":PRINT"YOU ONLY HAVE ";
2430 IFSU=10,PRINT"10 DAYS";ELSEIFSU<10ANDSU>=2,PRINTUSING"# DAYS";SU;
2440 IFSU<=1,PRINT"1 DAY";
2450 IFSU<=10,PRINT" OF SUPPLIES (FOOD, WATER, ETC.) LEFT!":GOSUB31350
2460 IFSD>88,TL=98-SD:PRINT"YOU ARE RUNNING OUT OF TIME!"
2470 IFTL=10,PRINT"THERE ARE ONLY 10 DAYS LEFT!"ELSEIFTL>0ANDTL<10ANDTL<>1,PRINTUSING"THERE ARE ONLY #.## DAYS LEFT!";TL
2480 IFTL=1,PRINT"THERE IS ONLY 1 DAY LEFT!"
2490 IFTL>0,G3=1
2500 IFTC>=170,PRINT"YOU ARE RUNNING OUT OF ACTIVE CREW MEMBERS!":PRINTUSING"### WERE KILLED";KC:PRINTUSING"### WERE INJURED";IC
2510 IFTC>=170,PRINTUSING"ONLY ### CREW MEMBERS LEFT!";500-TC:G3=1
2520 IFG3,GOSUB31350
2599 RETURN
2600 'SUB ARROW
2699 VM=15360+LO*64+CO:POKEVM,60:POKEVM+1,45:RETURN
2700 'SUB WT.OR.PRS.KY
2710 IFCM>1,WT=WT*CS(CM)/1.77
2720 IFCM<5ORCM=6,Z$=INKEY$:FORQQ=1TOWT:Z$=INKEY$
2730 IFCM=7ORCM=8,FORQQ=1TOWT:GETZ$
2740 IFZ$<>"",IFASC(Z$)=13,2799
2750 Z=VAL(Z$):IFZ$<>"",QQ=WT
2799 NEXTQQ:RETURN
2800 'SUB WM.H.DAT
2810 WT=151:GOSUB3100:W2=0:FORZ=1TONW:PRINT".";:WX=INT(W(Z)/10):WY=W(Z)-10*WX:IFWX=XANDWY=Y,W2=Z:Z=NW
2820 NEXT:PRINT:PRINT:IFW2=0,PRINT"CANNOT FIND ANY WORM HOLE DATA  FOR THIS SECTOR":RETURN
2830 PRINT:PRINT"WORM HOLE DATA FOR THIS SECTOR":Q=X:Z=Y:GOSUB7200
2840 PRINT"GOES TO":PRINT"SECTOR ";:IF(W2/2)=INT(W2/2),WD=-1ELSEWD=1
2899 WX=INT(W(W2+WD)/10):WY=W(W2+WD)-10*WX:Q=WX:Z=WY:GOSUB7200:RETURN
2900 'SUB PR.CURR.LOC.GIVEN.X,Y
2999 PRINT"YOU ARE CURRENTLY IN SECTOR  -  ";:Q=X:Z=Y:GOSUB7200:RETURN
3000 'SUB +-.SH
3010 '-, SI<SH
3020 IF(SH-SI)>=0,SA=SN:IF(SH+SA)<SI,SA=SI-SH
3030 '+, SI>SH
3040 IF(SH-SI)<0,SA=SX:IF(SH+SA)>SI,SA=SI-SH
3099 RETURN
3100 'SUB CL.SCRN.&.PUT.IN.32CPL
3110 GOSUB3700:IFCM<5,PRINTCHR$(23);
3199 ML=32:RETURN
3200 'SUB SH.INT
3210 '+- SH
3220 GOSUB3000:IFSH$=R$,SA=0
3230 E=E-ABS(SA):SH=SH+SA:IFSH$=Y$ANDSH>80,SH=80
3299 GOSUB1300:RETURN
3300 'SUB FAILURE/SUCCESS/NEITHER
3310 IFSD>98ORE<=0ORSU<=0ORTC>200ORBD>98ORSH<0OROT>2,A1$="FAILURE"ELSEA1$="NEITHER"
3320 IFSD<98ANDXH<0ANDSU>0ANDTC<200ANDBD<98ANDSH>=0ANDOT<3,A1$="SUCCESS"
3399 RETURN
3400 'SUB INEPT
3410 IFBD>97,PRINT"BECAUSE YOU WERE BLOWN UP BY AN ENEMY SHIP,"
3420 IFSD>98,PRINT"BECAUSE OF THE STARDATE BEING > 98,"
3430 IFE<=0,PRINT"BECAUSE YOU RAN OUT OF ENERGY,"
3440 IFSU<=0,PRINT"BECAUSE YOU RAN OUT OF SUPPLIES,"
3450 IFTC>=200,PRINT"BECAUSE TOO MANY OF THE CREW EITHER DIED OR WERE INJURED,"
3460 IFSH<0,PRINT"BECAUSE OF THE SHIELDS BEING < 0,"
3470 IFOT>2,PRINT"BECAUSE YOU TOOK TOO LONG TO MAKE DECISIONS,"
3499 PRINT"YOU WERE INEPT!":PRINTSTRING$(64,A2);:RETURN
3500 'SUB SH.INT.RPT
3510 IFZ<>1ANDSR=0,RETURN
3520 GOSUB3100:PRINT"SHIELD INTENTION REPORT":PRINT:PRINTUSING"SHIELDS CURRENTLY AT ###%";SH:PRINT"THE SHIELD SYSTEM IS "SH$:IFSH$=R$,PRINT"* SHIELDS INOPERABLE & SET=0 *":SH=0
3530 IFOA<>101,PRINT"THE ADJUSTMENT RATE WAS:":PRINTUSING"###%";SA
3540 PRINTUSING"SHIELD INTENTION IS ###%";SI:IFZ<>1,3580
3550 'SH INT
3560 PRINT:PRINT"WHAT DO YOU INTEND THE SHIELDS  TO BE SET AT (21-100 (DEFAULT))";:INPUTSI$:IFSI$="",SI$="100"
3570 SI=VAL(SI$):IFSI<21ORSI>100,3560
3580 '+- SH
3590 GOSUB3000:IFSH$=R$,SA=0
3600 IFOA=SA,PRINT:PRINT"THE ADJUSTMENT RATE STAYS THE   SAME AT:":PRINTUSING"###%";SA;:IFSA=SX,PRINT" - THE MAX"ELSEIFSA=SN,PRINT" - THE MIN"
3610 IFOA<>SA,OA=SA:PRINT:PRINT"THE NEW ADJUSTMENT RATE IS:":PRINTUSING"####%";SA;:IFSA=SX,PRINT" - THE MAX"ELSEIFSA=SN,PRINT" - THE MIN"ELSEPRINT
3620 E=E-ABS(SA):SH=SH+SA:GOSUB1300
3630 IFSH$=Y$ANDSH>80,SH=80:PRINT"SHIELDS DAMAGED!  80% IS THE":PRINT"MAXIMUM AVAILABLE!"
3640 PRINT:PRINT"THE SHIELDS HAVE BEEN ";:IFSH=0,PRINT"SHUT OFF!":PRINT"<DANGER> THE ENTERPRISE,":PRINT"HERSELF, WILL TAKE THE HITS!"ELSEPRINT"SET TO:  ":PRINTUSING"###%";SH
3650 IFSR,WT=221:GOSUB31350
3699 RETURN
3700 'SUB CLR SCR
3710 'TRS-80 & GW-BASIC
3720 IFCM<6,CLS
3730 'APPLE IIE
3740 IFCM=6,CALL-936
3750 'C64
3760 IFCM=7,PRINT CHR$(147) ;
3770 'C128
3780 IFCM=8,SCNCLR
3790 ML=64
3799 RETURN
3800 'SUB SU
3899 GOSUB3100:PRINT"SUPPLY STATUS":PRINT:PRINT"DAYS OF SUPPLIES LEFT - "SU:RETURN
3900 'SUB REMAINING.SC
3999 GOSUB3100:PRINT"REMAINING "S9$" = "TS:WT=91:RETURN
4000 'SUB SET.WX,WY,W9
4099 WX=RND(7):WY=RND(7):W9=10*WX+WY:RETURN
4100 'SUB SC.INT
4120 IFEA=0,RETURN
4130 IFSC=0,PRINT:PRINT"THERE IS NO "S9$"TO INTERFERE.":RETURN
4140 IFRND(100)>98,PRINT:PRINT"THE "S9$"MALFUNCTIONED!":E=E-2555-RND(166):GOSUB5100:RETURN
4150 NS=0:IFSC>=EA,GL=EAELSEGL=SC
4160 IFNS=GL,4330ELSEWS=RND(8):IFSS(WS)=0,4160ELSESS(WS)=0:ONWSGOSUB4170,4190,4210,4230,4250,4270,4290,4310:GOSUB4400:GOTO4160
4170 '-1,-1
4180 IF(A-1)>0AND(B-1)>0,IFS(A-1,B-1)=67,S(A-1,B-1)=46:RETURN
4190 '-1,0
4200 IF(A-1)>0,IFS(A-1,B)=67,S(A-1,B)=46:RETURN
4210 '-1,+1
4220 IF(A-1)>0AND(B+1)<8,IFS(A-1,B+1)=67,S(A-1,B+1)=46:RETURN
4230 '+1,-1
4240 IF(A+1)<8AND(B-1)>0,IFS(A+1,B-1)=67,S(A+1,B-1)=46:RETURN
4250 '+1,0
4260 IF(A+1)<8,IFS(A+1,B)=67,S(A+1,B)=46:RETURN
4270 '+1,+1
4280 IF(A+1)<8AND(B+1)<8,IFS(A+1,B+1)=67,S(A+1,B+1)=46:RETURN
4290 '0,-1
4300 IF(B-1)>0,IFS(A,B-1)=67,S(A,B-1)=46:RETURN
4310 '0,+1
4320 IF(B+1)<8,IFS(A,B+1)=67,S(A,B+1)=46:RETURN
4330 IFNS>0,PRINT@384,"BUT, THE "S9$"TOOK DAMAGE AND BLEW UP."
4340 FORI=GL+1TOEA:E=E-500-RND(400):NEXT:IFNS=EA,PRINTS9$"HAS PROTECTED THE ENTERPRISE AND ITS INHABITANTS"ELSEPRINT:PRINT"THE ENTERPRISE HAS BEEN DAMAGED"
4399 RETURN
4400 'SUB UPD.NS.&.SC
4499 NS=NS+1:SC=SC-1:RETURN
4500 'SUB GET.COORD.SYS
4510 PRINTCX$:IFRD<2,PRINT:PRINT"THE CURRENT"CX$"IS THE":IFRD,PRINT"STANDARD CARTESIAN"CX$:Z$="G":GOTO4590ELSEPRINT"GAME"CX$:Z$="S":GOTO4590
4515 PRINT:PRINT"CARTESIAN"CX$TAB(35)"GAME"CX$:FORI=7TO1STEP-1:PRINTTAB(5)I"......."TAB(39)8-I".......":NEXT
4517 PRINTTAB(7)"COLUMN X"TAB(41)"COLUMN Y";:PRINT@257,"ROW";:PRINT@291,"ROW";:PRINT@356,"X-";:PRINT@322,"Y-";
4520 PRINT@704,"WHICH"CX$"DO YOU PREFER:":PRINT:PRINT"THE (S)TANDARD CARTESIAN"CX$"...OR...":PRINT"THE (G)AME"CX$"(X & Y REVERSED, X RUNS BACKWARDS)"
4540 WT=851:GOSUB2700:IFZ$="",Z$="G"
4550 IFASC(Z$)=13,Z$="G"
4560 IFZ$="s",Z$="S"
4570 IFZ$="g",Z$="G"
4580 IFZ$<>"S"ANDZ$<>"G",GOTO4540
4585 PRINT@704,S0$:PRINT:PRINT:PRINT:PRINT@704,;
4590 PRINT:PRINT"THE"CX$"IS SET TO THE ";:IFZ$="S",RD=1:PRINT"STANDARD CARTESIAN":PRINTCHR$(8);ELSERD=0:PRINT"GAME";
4599 PRINTCX$:WT=341:RETURN
4600 'SUB CONTACT.US
4610 GOSUB3100:PRINT@198,:CE$="IF YOU HAVE ANY PROBLEMS":GOSUB7900:CE$="OR WOULD LIKE THE MODEL TUNED":GOSUB7900:CE$="DIFFERENTLY, PLEASE":GOSUB7900:PRINT
4699 CE$="EMAIL AL AT":GOSUB7900:CE$="al888000@proton.me":GOSUB7900:PRINT:CE$="OR TEXT A MESSAGE TO:":GOSUB7900:CE$="(248) 255-9816":GOSUB7900:WT=941:GOSUB31350:RETURN
4700 'SUB INIT.#S
4710 'EXPRESSED IN KHZ:  1 - MODEL I, 2 - MODEL II, 3 - MODEL III, 4 - MODEL 4, 5 - GW-BASIC, A ONE-OFF BECAUSE OF ITS UNIQUE WAY OF HANDLING STRINGS, 6 - APPLEIIE, 7 - C64, 8 - C128
4720 'CS STARTS OUT AS CLOCK SPEED, BUT TURNS INTO COMPUTER SPEED BECAUSE THERE ARE MANY FACTORS INFLUENCING A COMPUTER'S "SPEED".  CLOCK SPEED IS ONLY MEANT AS A STARTING POINT.
4730 CM=1:CS(2)=4:CS(3)=2.02572:CS(4)=4:CS(5)=20:CS(6)=1.023:CS(7)=2.2833:CS(8)=CS(7)*2
4799 RD=2:HA=1:OA=101:TS=24:DC=-1:LR=1:SX=100:SN=-100:CA=500:E=15000:SI=100:SH=100:TP=10:FT=10:KT=15:RT=10:RETURN
4800 'SUB NAV.MODE
4810 PRINT"NAVIGATION":PRINT:PRINTEO$:PRINT:PRINT"SHORT (WITHIN SECTOR) ";:IFID$<>R$ANDSC=0,PRINT"  - 1 ";ELSEPRINT"XXXXX RED";:IFSC>0,PRINT"/":PRINT"   "S9$:PRINT"PRESENT";
4815 IFID$=Y$,PRINTY$ELSEPRINT
4820 PRINT"LONG (SECTOR TO SECTOR) ";:IFWD$<>R$ANDSC=0,PRINT"- 2 ";ELSEPRINT"XXX RED";:IFSC>0,PRINT"/":PRINT"SPACE CHAFF PRESENT";
4825 IFWD$=Y$,PRINTY$ELSEPRINT
4830 IFID$=R$ANDWD$=R$,PRINT:PRINT"YOU'RE DEAD IN THE WATER"WI$"BOTH ENGINES OUT!":RETURN
4840 PRINT@512,;:GOSUB2900:GOSUB5800:PRINT@704,;:CE$=PW$:GOSUB7900:GOSUB9900:PRINT@704,S0$;
4850 PRINT@704,;:GOSUB30000
4860 IFZ$="0",PRINTBS$"NAVIGATION MENU ABORTED":RETURN
4870 IFZ=0OR(Z=1ANDID$=R$)OR(Z=2ANDWD$=R$)ORZ>2,GOTO4850
4880 IFZ=1,LO=4:IFID$=Y$,CO=35:GOSUB2600ELSECO=29:GOSUB2600
4899 CH=Z:ONZGOSUB5200,4900:RETURN
4900 'SUB LR MOVE
4910 GOSUB3700:PRINT"LR MOVE":PRINT:AD$="NEARBY "
4915 PRINT"ENERGY ="E:PRINT"THE BUY-IN COST FOR WARPING = 500 ENERGY UNITS"
4917 IFWD$=Y$,PRINT"CAN'T GO MORE THAN 2 SECTORS"WI$"WARP DRIVE "Y$:WM=2:AD$="VERY "+AD$ELSEWM=10
4920 GOSUB10700:PRINT@384,;:DE$="SECTOR":GOSUB6900:IFL=0ORD=0,FORQ=1TO6:PRINT:NEXT:RETURN
4922 IFRD,F1=X-D:F2=Y-LELSEF1=Y-8+D:F2=X-L
4925 DS=SQR(F1*F1+F2*F2):PRINT"DISTANCE IS"DS"PARSECS":FORJ=1TO7:PRINT:NEXT:IFDS>WM,PRINT"YOU CAN'T GO THAT FAR!":WT=262:RETURN
4930 IFDS=0,GOSUB3100:PRINT:PRINT"LR MOVE ABORTED!  DISTANCE IS 0":PRINT"THE ENTERPRISE IS THERE!":WT=271:RETURN
4935 WT=221:GOSUB31350
4940 'SHOW WARPING NEEDS
4950 GOSUB6300
4955 'GET WF
4960 PR=704:GOSUB6800:IFSP$="0",PRINT:PRINT"WARPING ABORTED!  ZERO SPEED SPECIFIED":RETURNELSEWF=FA
4970 IFWF=0ORWF>WM,4955
4980 'BLACKHOLE?
4990 BH=0:IFRND(10)>2,5010
5000 BH=1:L=RND(7):D=RND(7):IFL=XANDD=Y,5000
5010 'SHOW E @ WARP SPD
5020 GOSUB7700:IFBH=1,DS=4.9
5030 'MVE TO S
5040 EU=500+(WF*DS+SH*WF*DS+WF*100)/3:TU=DS/WF:E=E-EU:SD=SD+TU:IFRD,X=D:Y=LELSEX=L:Y=D
5050 'CLR S
5060 GOSUB1100
5070 'GET S DAT, CODE & RETURN
5099  GOSUB8900:GOSUB10200:RETURN
5100 'SUB CREW.KILLED-INJ
5110 IFEA=0,RETURN
5120 CP=RND(10):IFCP>5,CK=RND(6):CI=RND(9):PRINT@448,USING"CREW MEMBERS HAVE BEEN KILLED (#";CK;:PRINTUSING") AND INJURED (#";CI;:PRINT")!"
5130 IFCP>5,CA=CA-CK-CI:KC=KC+CK:IC=IC+CI:TC=TC+CK+CI:IFTC>0,PRINT"THAT'S A TOTAL OF"TC"OR"TC/2"% OF THE 200!"
5199 RETURN
5200 'SUB SR MVE
5210 PRINT@512,"YOU ARE CURRENTLY AT COORDINATES ";:IFRD,PRINTUSING"#!# IN "+CC$;A,",",BELSEPRINTUSING"#!# IN "+GC$+" ";8-B,",",A
5220 PRINT"THE BUY-IN COST FOR A SR MOVE IS 250 ENERGY UNITS":AD$="NEARBY ":IFID$=Y$,PRINT"CANNOT MOVE MORE THAN 2 COORDINATE UNITS"WI$"IMPULSE DRIVE     "Y$:MI=2:AD$="VERY "+AD$ELSEMI=10
5230 PRINT:DE$="COORDINATES":GOSUB6900
5240 IFD=0ORL=0,RETURN
5245 IFRD,SL=S(D,L):F1=A-D:F2=B-LELSESL=S(L,8-D):F1=A-L:F2=B-8+D
5247 IFNOT(SL=46OR(SL=66ORSL=83)ORSL=87),PRINT:PRINT"CANNOT MOVE THERE - AN OBJECT IS THERE!":WT=242:RETURN
5250 DS=SQR(F1*F1+F2*F2):PRINT"DISTANCE IS"DS" COORDINATE UNITS":IFDS>MI,PRINT:PRINT"YOU CAN'T GO THAT FAR!":WT=222:RETURN
5252 IFDS=0,PRINT:PRINT"SR MOVE ABORTED - DISTANCE IS ZERO!":WT=222:RETURNELSEPRINT:WT=191:GOSUB2700
5256 FORQ=1TOMI:IFE<250+(Q*DS+SH*DS*Q)/3,Z=Q-1:Q=MI:MI=Z:NEXTELSENEXT
5258 IFMI=0,PRINT"CANNOT MOVE, NOT ENOUGH ENERGY!":WT=261:GOSUB31350:RETURN
5260 PRINT@512,S0$;:PRINT@512,"IMPULSE":PRINT" DRIVE";:FORI=1TOMI:PRINTUSING"###.#";I;:NEXT:PRINT:PRINT" TIME":PRINT"NEEDED";:FORI=1TOMI:PRINTUSING"###.#";DS/I;:NEXT:PRINT
5270 PRINT"ENERGY":PRINT"NEEDED";:FORI=1TOMI:PRINTUSING"#####";250+(I*DS+SH*DS*I)/3;:NEXT:PRINT
5280 'GET SPEED
5290 PR=0:GOSUB6800:IFSP$="0",RETURNELSEIM=FA
5295 PRINT@512,S0$:FORQ=1TO5:PRINT:NEXT:PRINT@512,;
5300 'RESUP & REPD
5310 IF(SL=66ORSL=83)ANDIM=1,NN=SL:SU=46:SD=SD+1:RS=SD:PRINT@256,"YOU HAVE BEEN TOTALLY":PRINT@320,"RESUPPLIED WITH":PRINT@384,"FOOD AND WATER"
5320 IFSL=83ANDEV>0ANDRND(99)>12,PRINT@576,"SUPPLY PLANET WAS DESTROYED BY HOSTILES!":G(X,Y)=G(X,Y)-100:IFNN=83,NN=46
5340 IFSL=66ANDIM=1,E=15000:RE=RE+TC:TC=0:CA=0:TP=10:TS=24:PRINT"YOU HAVE ALSO BEEN GIVEN 15,000 UNITS OF ENERGY, A MOTIVATED":PRINT"CREW, 10 PHOTON TORPEDOES, AND A TOTAL OF 24 UNITS OF":PRINT"SPACE CHAFF"
5345 IFSL=66ANDIM=1,GOSUB6600:PRINT"THE FEDERATION STARBASE HAS ALSO REPAIRED ALL YOUR SUBSYSTEMS"
5350 IFSL=66ANDEV>0ANDRND(99)>92,PRINT:PRINT"FEDERATION STARBASE WAS DESTROYED BY HOSTILES":G(X,Y)=G(X,Y)-1000:IFNN=66,NN=46
5370 IFIM=1ANDSL=83ANDID$=Y$,PRINT:PRINT"CANNOT ORBIT A SUPPLY PLANET"WI$"IMPULSE DRIVE "Y$"!":RETURN
5380 IFIM=1ANDSL=66ANDID$=Y$,PRINT:PRINT"CANNOT DOCK"WI$"A FEDERATION STARBASE"WI$"IMPULSE DRIVE     "Y$:RETURN
5390 EU=250+(IM*DS+SH*DS*IM)/3
5400 SD=SD+DS/IM:E=E-EU:IFNF=0OR(NN=46AND(NF<>83ANDNF<>66)),S(A,B)=46:NN=0ELSES(A,B)=NF:NF=NN:NN=46
5410 'MAKE SR MOVE
5420 IFSL<>87,IFRD,S(D,L)=69:A=D:B=LELSES(L,8-D)=69:A=L:B=8-D
5425 IFSL<>87,PRINT@512,"SUCCESSFUL SR MOVE":CE$=PW$:GOSUB7900:PRINT@41,STRING$(21,32);:GOSUB9900:PRINT@576,S0$;:RETURN
5430 PRINT@512,"WORM HOLE DETECTED"
5440 WH=WH+1:IFWH<=NW,IFW(WH)<>10*X+Y,5440ELSEIFWH>NW,PRINT"LINE 5440 - WORM HOLE NOT FOUND!":END
5450 'GET OTHER END OF W H - IF THE CURR W H IS EVEN NUMBERED (AN ENDING), DELTA IS -1.  IF ODD NUMBERED (A BEGINNING), DELTA IS +1.
5460 IFWH/2=INT(WH/2),WD=-1ELSEWD=1
5470 WV=INT(W(WH+WD)/10):WW=W(WH+WD)-10*WV
5490 Q=X:Z=Y:GOSUB7300
5500 'MAKE W H MOVE
5510 X=WV:Y=WW:BH=0:PRINT"FROM-TO ";:Q=X:Z=Y:GOSUB7300
5520 PRINT"SUCCESSFUL WORM HOLE MOVE"
5530 'MAKE CURR S VAC, GET S DAT AND CODE S
5599 GOSUB1100:GOSUB8900:GOSUB10200:RETURN
5600 'SUB COMP
5610 PRINT"COMPUTER ";:IFCS$=Y$,PRINTY$ELSEPRINT
5620 PRINT:IFCS$=R$,PRINT"COMPUTER SYSTEMS ARE OUT!"RP$:SD=SD-.5:RETURN
5630 IFCS$=Y$,OC=0:FORI=1TO9:OO(I)=0:NEXTELSE5650
5640 IFOC<4,OD=RND(9):IFOO(OD)=0,OC=OC+1:OO(OD)=1:GOTO5640ELSE5640ELSE5650
5650 PRINTEO$:PRINT:PRINT"ALL SECTORS THAT HAVE BEEN VISITED/COVERAGE";:IFCS$=G$OR(CS$=Y$ANDOO(1)=1),PRINT" - 1"ELSEPRINT" - X"
5660 PRINT"DAMAGE CONTROL REPORT";:IFCS$=G$OR(CS$=Y$ANDOO(2)=1),PRINT" . 2":ELSEPRINT" . X"
5670 PRINT"SUPPLY STATUS";:IFCS$=G$OR(CS$=Y$ANDOO(3)=1),PRINT" - 3"ELSEPRINT" - X"
5680 PRINT"CREW STATUS";:IFCS$=G$OR(CS$=Y$ANDOO(4)=1),PRINT" . 4"ELSEPRINT" . X"
5690 PRINT"ABBREVIATIONS";:IFCS$=G$OR(CS$=Y$ANDOO(5)=1),PRINT" - 5"ELSEPRINT" - X"
5700 PRINT"LR SCAN";:IFCS$=G$OR(CS$=Y$ANDOO(6)=1),PRINT" . 6"ELSEPRINT" . X"
5710 PRINT"GET NAV DATA";:IFCS$=G$OR(CS$=Y$ANDOO(7)=1),PRINT" - 7"ELSEPRINT" - X"
5720 PRINT"WORM HOLE DATA ON THIS SECTOR";:IFCS$=G$OR(CS$=Y$ANDOO(8)=1),PRINT" . 8"ELSEPRINT" . X"
5730 PRINT"# OF UNITS OF "S9$"LEFT";:IFCS$=G$OR(CS$=Y$ANDOO(9)=1),PRINT" . 9"ELSEPRINT" . X"
5740 PRINT@832,;;:GOSUB30000:IFZ$="0",PRINTBS$:PRINT"COMPUTER MENU ABORTED":RETURNELSEIFZ=0,PRINTBS$;:GOTO5740
5750 IFCS$=Y$ANDOO(Z)=0,PRINT:PRINT"THAT OPTION DOESN'T EXIST":GOTO5740
5760 IFZ=6,C6=1
5799 GOSUB3700:ONZGOSUB8100,5900,3800,6000,6700,10700,6200,2800,3900:C6=0:D=0:RETURN
5800 'SUB PR.WITH.EV.VEHICLES
5810 PRINT"WITH"EV"ENEMY VEHICLE";:IFEV<>1,PRINT"S"ELSEPRINT
5899 RETURN
5900 'SUB DMG.CTRL
5910 PRINT"DAMAGE CONTROL REPORT:":PRINT:IFSH<21,DA$="SHIELDS:"ELSEDA$=""
5920 IFCS$=R$,DA$=DA$+"COMPUTER:"
5930 IFWD$=R$,DA$=DA$+"WARP DRIVE:"
5940 IFID$=R$,DA$=DA$+"IMPULSE DRIVE:"
5950 IFPB$=R$,DA$=DA$+"PHASER BANKS:"
5960 IFTP$=R$,DA$=DA$+"TORPEDO LAUNCH:"
5970 IFDA$="",DA$="NONE:"
5999 PRINT"SYSTEMS INOPERABLE:":PRINTLEFT$(DA$,LEN(DA$)-1):RETURN
6000 'SUB CREW.STAT
6010 PRINT"CREW STATUS":PRINT:PRINT"CREW AT START OF THIS MISSION ... 500"
6020 PRINT"CREW KILLED ON THIS MISSION - - - "USING"###";KC:PRINT"CREW INJURED ON THIS MISSION .....";USING"###";IC
6099 PRINT"CREW REPLENISHED - - - - - - - - - "RE:PRINT"CREW REMAINING ON ACTIVE DUTY ... "USING"###";500-CA:RETURN
6100 'SUB SH-CHAFF
6110 PRINT"SHIELDS-CHAFF":PRINT
6120 PRINTEO$:PRINT:PRINT"ADJUST SHIELD INTENTION ..... ";:IFSH$<>R$,PRINT"1"ELSEPRINT"X RED"
6125 IFSR=0,PRINT"TURN ON SHIELD REPORT ....... 2"ELSEPRINT"TURN OFF SHIELD REPORT  - - - 2"
6130 IFSC=0,PRINT"DEPLOY "S9$".......... 3"ELSEPRINT"DE-ACTIVATE "S9$"- -  3"
6140 GOSUB30000:IFZ>3,PRINTBS$;:GOTO6140
6150 IFZ$="0",PRINTBS$:PRINT"SHIELDS-CHAFF MENU ABORTED":RETURNELSEIFZ=0,PRINTBS$;:GOTO6140
6160 IFZ=1ANDSH$=R$,PRINTBS$;:GOTO6140
6199 PRINT:ONZGOSUB3500,2200,1700:RETURN
6200 'SUB GET.NAV.DAT
6210 GOSUB2900:GOSUB5800
6220 PRINT"ENTER THE SECTOR YOU WANT DATA ON, IN ";:IFRD,PRINTCC$;ELSEPRINTGC$;
6230 I=0:J=0:INPUTI,J
6240 IFI<1ORI>7ORJ<1ORJ>7,GOSUB7400:GOTO6200
6245 IFRD,G8=G(I,J)ELSEG8=G(J,8-I)
6250 Q=1000000:F8=INT(G8/Q):G8=G8-F8*Q:Q=Q/10:W8=INT(G8/Q):G8=G8-W8*Q
6260 Q=Q/10:S8=INT(G8/Q):G8=G8-S8*Q:Q=1000:B8=INT(G8/Q):G8=G8-B8*Q
6270 P8=INT(G8/100):G8=G8-P8*100:K8=INT(G8/10):R8=G8-K8*10:E8=F8+K8+R8
6280 PRINT"ENERGY = "E:PRINTUSING"SHIELDS = ###%";SH:PRINT"DATA ON SECTOR ";:Q=I:Z=J:GOSUB7200
6290 PRINT:IFI=XHANDJ=YH,B8=B8+1
6299 PRINT"WORM HOLES"W8"STARS"S8"BASES"B8"SUPPLY PLANETS"P8"+ENEMY VESSELS"E8:RETURN
6300 'SUB SHOW.WARPING.INFO
6320 FORQ=1TOWM:IFE<500+(Q*DS+SH*DS*Q+Q*100)/3,Z=Q-1:Q=WM:WM=Z:NEXTELSENEXT
6325 IFWM=0,PRINT"CANNOT WARP, NOT ENOUGH ENERGY!":WT=261:GOSUB31350:RETURN
6330 PRINT"WARP":PRINT"FACTOR";:FORI=1TOWM:PRINTUSING"###.#";I;:NEXT:PRINT
6399 PRINT"ENERGY":PRINT"NEEDED";:FORI=1TOWM:EU=500+(I*DS+SH*DS*I+I*100)/3:PRINTUSING"#####";EU;:NEXT:PRINT:PRINT"  TIME":PRINT"NEEDED";:FORI=1TOWM:PRINTUSING"###.#";DS/I;:NEXT:PRINT:RETURN
6400 'SUB CENTER AND UNDERLINE CU$
6410 CE$=CU$:GOSUB7900
6499 CE$=STRING$(LC,45):GOSUB7900:RETURN
6500 'SUB SET.CO$
6510 CO$=G$:IFSH$>CO$ORCS$>CO$ORID$>CO$ORWD$>CO$ORPB$>CO$ORTP$>CO$,CO$=Y$
6520 IFE<5000,CO$=R$
6599 RETURN
6600 'SUB SET.ALL.GYRS.TO.GR
6699 SH$=G$:CS$=G$:WD$=G$:ID$=G$:PB$=G$:TP$=G$:CO$=G$:RETURN
6700 'SUB ABBRS
6799 GOSUB3700:PRINT"ABBREVIATIONS":PRINT:GOSUB9600:RETURN
6800 'SUB GET.SPD
6810 IFCH=1,SM=MI
6820 IFCH=2,SM=WM
6830 IFPR,PRINT@PR,;
6840 PRINTUSING"AT WHAT SPEED DO YOU WANT TO TRAVEL 0 TO ##";SM;
6850 INPUT" (DEFAULT)";SP$:IFSP$="0",RETURN
6860 IFSP$="",FA=SMELSEFA=VAL(SP$)
6870 IFFA=0ORFA>SM,6840
6880 IFFA<0,PRINTUSING"SPEED MUST BE BLANK FOR DEFAULT OR 0-##";SM:GOTO6800
6899 RETURN
6900 'SUB GET.DEST
6910 D=0:L=0:PRINT"MOVE TO "AD$DE$" IN ";:IFRD,PRINTCC$;ELSEPRINTGC$;
6920 INPUTD,L:IFL=0ORD=0,PRINT:PRINT"MOVE ABORTED!  ZERO COORDS SPECIFIED":WT=161:RETURN
6930 IFL<1ORL>7ORD<1ORD>7,GOSUB7400:GOTO6900
6940 IFRD=0,Z=D:D=L:L=Z
6999 RETURN
7000 'SUB AB.SHIP
7010 GOSUB3100:PRINT"DO YOU REALLY WANT TO ABANDON":INPUT"SHIP (DEFAULT = YES OR NO )";AB$:IFAB$="n"ORAB$="N"ORAB$="no"ORAB$="NO",RETURN
7099 GOSUB1200:GOSUB3100:PRINT@512,"ABANDONING SHIP!"
7100 'PLAY.AGAIN?
7110 IFBD>97,PRINT:PRINT"YOU WERE BLOWN UP BY THE ENEMY!"
7120 IFBD<97ANDOT=3,PRINT:PRINT"YOU RAN OUT OF TIME TO MAKE DECISIONS!"
7198 PRINT@960,;:INPUT"DO YOU WANT TO PLAY AGAIN? (YES OR NO = DEFAULT)";PA$:IFPA$="yes"ORPA$="YES"ORPA$="y"ORPA$="Y",RUNELSEPRINT:PRINT"NO":END
7200 'SUB PR.COORDS.WITH.COORD.SYS
7210 GOSUB7300:IFLR,IFRD,PRINT"IN "CC$ELSEPRINT"IN "GC$ELSEPRINT
7299 RETURN
7300 'SUB PR.COORDS
7310 IFLR,IFRD,PRINTUSING"(#!#) ";Q,",",Z;ELSEPRINTUSING"(#!#) ";8-Z,",",Q;ELSEPRINT"(?,?) ";
7399 RETURN
7400 'SUB INVALID.COORDS
7499 PRINT"INVALID COORDINATES WERE GIVEN!":RETURN
7500 'SUB BLOW.UP.OR.SCORCH
7510 IFRD,BX=V:BY=WELSEBX=W:BY=V
7520 VM=BY*64+BX*3+15398:FORJ9=1TO30:POKEVM,128+RND(64):NEXT:GOSUB21000:IFS1,POKEVM,42:S(BX,BY)=42ELSEPOKEVM,46:S(BX,BY)=46
7599 RETURN
7600 'SUB SETUP.S
7610 PRINT".";:IFCN>0,L=RND(7):N9=RND(7)ELSERETURN
7620 IFS(L,N9)=46,S(L,N9)=SY:CN=CN-1:GOTO7610ELSE7610
7699 RETURN
7700 'SUB SHOW.ENT.AT.WARP.SPD
7710 GOSUB3700:PRINT@320,;:Q=X:Z=Y:GOSUB7300:IFBH,PRINT@600,"OH NO, A BLACKHOLE!":LR=0
7720 FORJ=384TO441:PRINT@J,EN$:FORI=1TO(10-WF):NEXTI,J
7730 PRINT@379,;:IFLR,IFRD,PRINTUSING"(#!#)";D,",",L;ELSEPRINTUSING"(#!#)";L,",",D;ELSEPRINT"(?,?)";
7799 RETURN
7900 'SUB CENTER CE$
7910 'JUST PRINT ANY STRING WHOSE LEN>=ML-1
7920 LC=LEN(CE$):IFLC>=ML-1,IFLC=ML,PRINTCE$;:RETURNELSEPRINTCE$:RETURN
7999 HL=INT((ML-LC)/2):PRINTSTRING$(HL," ")CE$;:IFCE$=PK$,RETURNELSEPRINT:RETURN
8100 'SUB BEEN-THERE
8110 GOSUB3700:PRINT"SECTORS IN THE ORDER THEY WERE VISITED AND THEIR COVERAGE":FORI=1TOSV
8120 IFRD,PRINTUSING"(#!#)->";XV(I),",",YV(I);:BT(XV(I),YV(I))=64ELSEPRINTUSING"(#!#)->";8-YV(I),",",XV(I);:BT(8-YV(I),XV(I))=64
8130 IFINT(I/4)=IORI=SV,PRINT"|"
8140 NEXTI:PRINT"IN ";:IFRD,PRINTCC$ELSEPRINTGC$
8150 IFOV,IFRD,BT(ABS(XH),YH)=72ELSEBT(8-YH,ABS(XH))=72
8160 PRINT@576,;:CE$=PW$:GOSUB7900:FORI=1TO7:FORJ=1TO7:IFRD,VM=15454+64*(7-J)+4*IELSEVM=15455+64*(I-1)+4*J
8165 IFBT(I,J)=0,BT(I,J)=46
8170 POKEVM,BT(I,J):IFBT(I,J)=64OR(BT(I,J)=72ANDXH<0),SE=SE+1
8180 NEXTJ,I:PRINT@576,S0$:IFSE=1,AD$="ONLY "ELSEAD$=""
8190 PRINT@640,"THAT'S "AD$SE" SECTOR";:IFSE>1,PRINT"S";
8199 PRINT" OR"SE/49*100"% COVERAGE!":WT=111:RETURN
8400 'SUB SH-DMG
8410 IFEA=0,RETURN
8420 IFSH<=0,PRINT@704,"SHIELDS ARE DAMAGED AND ARE LESS THAN OR EQUAL TO ZERO.":IFSC=0,PRINT"THE ENTERPRISE WILL TAKE THE FIRE.":FORJ=1TOEA:E=E-250-RND(300):NEXT:RETURN
8430 FORI=1TOEA:BD=RND(100)+EA:IFBD>98,GOSUB1200:GOSUB3100:PRINT@384,"OH NO, AN ENEMY GOT YOU!":WT=30:GOSUB2700:I=EA:NEXT:GOTO840ELSENEXT
8440 IFSC=0,PRINT@640,"SOME HOSTILE FIRE HAS HIT THE SHIELDS";:IFSH>80,PRINT", BUT BEEN DEFLECTED AWAY!"
8450 IFSC=0ANDSH<81ANDSH>20,PRINT", AND THE SHIELDS HAVE":FORI=1TOEA:DA=5+RND(5):IF(SH-DA)>0,SH=SH-DA:NEXTELSEE=E-300-RND(200):NEXT
8460 GOSUB1300:IFSC=0ANDSH<81,PRINTUSING"BEEN DAMAGED DOWN TO ##%.";SH;:IFSH$<>R$,PRINTRP$ELSEPRINT
8499 RETURN
8500 'SUB HOSTILES.MOVE
8525 IFEV=0,RETURNELSETE=0:GOSUB2000
8530 'LOOP THRU EACH ENEMY IN S, TE
8535 TE=TE+1:IFTE<=EV,Y9=INT(VE(TE)/10):X9=VE(TE)-Y9*10ELSERETURN
8540 'X MOVE
8545 IFX9=7,8575
8550 'MOVE DOWN 1, X9 + 1
8555 IFX9<7,IFA>X9ANDS(X9+1,Y9)=46,S(X9+1,Y9)=S(X9,Y9):S(X9,Y9)=46:X9=X9+1:GOTO8555
8560 IFX9=1,8575
8565 'MOVE UP 1, X9 - 1
8570 IFX9>1,IFA<X9ANDS(X9-1,Y9)=46,S(X9-1,Y9)=S(X9,Y9):S(X9,Y9)=46:X9=X9-1:GOTO8570
8575 IFY9=7,8535
8580 'MOVE RT 1, Y9+1
8585 IFY9<7,IFB>Y9ANDS(X9,Y9+1)=46,S(X9,Y9+1)=S(X9,Y9):S(X9,Y9)=46:Y9=Y9+1:GOTO8575
8590 'MOVE LT 1, Y9-1
8595 IFY9>1,IFB<Y9ANDS(X9,Y9-1)=46,S(X9,Y9-1)=S(X9,Y9):S(X9,Y9)=46:Y9=Y9-1:GOTO8595
8599 GOTO8535
8600 'SUB INIT.STRINGS
8610 S9$="SPACE CHAFF ":WI$=" WITH ":S0$=STRING$(63,32):EO$="END TURN  - - - - - 0":RP$="  REPAIRS ARE IN PROGRESS...":G$="GREEN ":Y$="YELLOW":R$="RED   "
8620 BS$=CHR$(8):CC$="CARTESIAN COORDS":GC$="GAME COORDS":PK$="PRESS ANY KEY TO CONTINUE"
8630 PW$="PLEASE WAIT...":CX$=" COORDINATE SYSTEM "
8640 'SIDE VIEW OF NCC-1701
8650 IFCM<5,EN$=CHR$(131)+CHR$(187)+CHR$(179)+CHR$(177)+CHR$(188)+CHR$(188)+CHR$(140)
8699 RETURN
8700 'SUB RESET.GYRS
8701 IFCS$=G$,IFRND(21)<5,CS$=Y$:GOTO8710
8702 IFCS$=Y$,CS$=R$:GOTO8710
8704 RY=RND(6):ONRYGOTO8706,8706,8706,8706,8708,8710
8706 CS$=G$:GOTO8710
8708 CS$=Y$
8710 IFWD$=G$,IFRND(21)<4,WD$=Y$:GOTO8720
8712 IFWD$=Y$,WD$=R$:GOTO8720
8714 RY=RND(6):ONRYGOTO8716,8716,8716,8716,8718,8720
8716 WD$=G$:GOTO8720
8718 WD$=Y$
8720 IFID$=G$,IFRND(21)<4,ID$=Y$:GOTO8730
8722 IFID$=Y$,ID$=R$:GOTO8730
8724 RY=RND(6):ONRYGOTO8726,8726,8726,8726,8728,8730
8726 ID$=G$:GOTO8730
8728 ID$=Y$
8730 IFPB$=G$,IFRND(21)<5,PB$=Y$:GOTO8750
8732 IFPB$=Y$,PB$=R$:GOTO8750
8735 RY=RND(6):ONRYGOTO8740,8740,8740,8740,8745,8750
8740 PB$=G$:GOTO8750
8745 PB$=Y$
8750 IFTP$=G$,IFRND(21)<5,TP$=Y$:GOTO8775
8755 IFTP$=Y$,TP$=R$:GOTO8775
8760 RY=RND(6):ONRYGOTO8765,8765,8765,8765,8770,8775
8765 TP$=G$:GOTO8775
8770 TP$=Y$
8775 IFSH$=G$,IFRND(21)<4,SH$=Y$:RETURN
8780 IFSH$=Y$,SH$=R$:RETURN
8785 RY=RND(6):ONRYGOTO8790,8790,8790,8790,8795,8799
8790 SH$=G$:RETURN
8795 SH$=Y$
8799 RETURN
8800 'SUB RANDOMLY.DEFINE.SECTORS
8810 FORI=1TO7:FORJ=1TO7:IFI=XHANDJ=YH,8899
8820 Q=1000000:GF=(RND(3)-1)*Q:Q=Q/100:GS=RND(6)*Q:IFRND(7)<3,GB=RND(2)*1000ELSEGB=0
8830 IFRND(8)<3,GP=100ELSEGP=0
8840 GK=RND(3)*10:IFGK>29,GR=RND(GK/10-1)-1ELSEGR=0
8845 G(I,J)=G(I,J)+GF+GS+GB+GP+GK+GR
8850 'MAX EV=3-1 + 3 + 3-1 = 7
8899 PRINT".";:NEXTJ,I:RETURN
8900 'SUB GET.S.DAT
8910 IFSV<51,SV=SV+1:XV(SV)=X:YV(SV)=Y
8920 GG=G(X,Y):Q=1000000:GF=INT(GG/Q):GG=GG-GF*Q:Q=Q/10:GW=INT(GG/Q):GG=GG-GW*Q
8930 Q=Q/10:GS=INT(GG/Q):GG=GG-GS*Q:Q=1000:GB=INT(GG/Q):GG=GG-GB*Q
8999 GP=INT(GG/100):GG=GG-GP*100:GK=INT(GG/10):GR=GG-GK*10:RETURN
9000 'SUB WEAPONS
9010 IFEV=0AND(X<>XHANDY<>YH),GOSUB2300:RETURN
9020 PRINT"WEAPONS":PRINT:IFPB$=R$ANDTP$=R$,PRINT"YOU DON'T HAVE ANY WEAPONS THAT WORK!":RETURN
9030 PRINT"ENERGY = "E:PRINT:PRINTEO$:PRINT:PRINT"* MEGA-PHASER * ";:IFE>=7000ANDPB$=G$,PRINT".....1"ELSEPRINT"XXXXXXX"
9040 PRINT"PHASER BANKS ";:IFPB$<>R$,PRINT"- - - - 2 ";ELSEPRINT"XXXXXXX RED";
9050 IFPB$=Y$,PRINTY$ELSEPRINT
9060 PRINT"PHOTON TORPEDOES ";:IFTP$<>R$,PRINT"....3 ";ELSEPRINT"XXXXX RED";
9070 IFTP$=Y$,PRINTY$ELSEPRINT
9075 GOSUB2900:GOSUB5800:PRINT@768,;:CE$=PW$:GOSUB7900:GOSUB9900:PRINT@768,S0$:PRINT@768,;
9080 GOSUB30000:IFZ>3,PRINTBS$;:GOTO9080
9090 IFZ$="0",PRINTBS$:PRINT"WEAPONS MENU ABORTED":RETURNELSEIFZ=0,PRINTBS$;:GOTO9080
9100 IF(Z=1ANDE<7000)OR(Z<3ANDPB$=R$)OR(Z=3ANDTP$=R$),PRINTBS$;:GOTO9080
9110 'WEAPON INIT
9120 IFZ=3,P1$="PHOTON TORPEDOES":P2$="":P3$=P1$ELSEP1$="PHASER BANKS":P2$=" BLAZIN'":P3$="ENERGY":IFZ=1,P1$="* MEGA-PHASER *"
9130 LO=Z+5:ONZGOSUB9140,9140,9160:GOSUB2600:GOTO9180
9140 IFPB$=G$,CO=23:RETURN
9150 IFPB$=Y$,CO=30:RETURN
9160 IFTP$=G$,CO=23:RETURN
9170 IFTP$=Y$,CO=30:RETURN
9180 'USE THE MEGA-PHASER
9190 IFZ=1,GOSUB2100:RETURN
9200 AD$="NEARBY":IF(Z=2ANDPB$=Y$)OR(Z=3ANDTP$=Y$),AD$="VERY "+AD$
9210 PRINT@768,"ENTER THE ";:IFRD,PRINTCC$;ELSEPRINTGC$;
9220 W=9:PRINT" OF THE "AD$" TARGET";:INPUTV,W
9225 IFV<1ORV>7ORW<1ORW>7,GOSUB7400:GOTO9210
9230 IF(RDANDV=AANDW=B)OR(RD=0ANDW=AAND8-V=B),PRINT:PRINT"THE ENTERPRISE IS AT THAT LOCATION!":GOSUB7400:WT=351:RETURN
9240 IFRD,FI=A-V:F2=B-WELSEF1=A-W:F2=B-8+Y
9250 DS=SQR(F1*F1+F2*F2):PRINT@512,S0$:PRINT"DISTANCE="DS
9255 IF((PB$=Y$ANDZ=2)OR(TP$=Y$ANDZ=3))ANDDS>2,PRINT:PRINT"CANNOT USE "P1$" WHEN TARGET IS MORE THAN 2":PRINT"COORDINATE UNITS AWAY AND "P1$" ARE "Y$"!":WT=351:RETURN
9260 'PHASERS - AMT OF E TO FIRE
9270 IFZ=2,GOSUB15200:IFWE$="0",PRINT:PRINTP1$" ABORTED!  WEAPON ENERGY 0":RETURN
9275 IFZ=2AND(WE=0ORWE>10),9270
9280 'PHASER BANKS - E USED
9290 IFZ=2,EU=E*WE/100
9300 IFRD,SW=S(V,W):I=V:J=WELSEI=V:J=8-W:SW=S(I,J)
9310 'PHOTON TORP - TORP & E USED
9320 IFZ=3,TP=TP-1:EU=350+RND(200)
9330 'TORP BLOW UP IN TUBE & CREW DEAD-INJ
9340 IFZ=3ANDRND(100)>95,PRINT"PHOTON TORPEDO BLEW UP IN TUBE!":PRINTUSING"ENERGY USED = ###.#";EU/2:E=E-EU/2:GOSUB5100:RETURN
9350 PRINTP1$P2$" AWAY!":E=E-EU:PRINTUSING"ENERGY USED = ###.#";EU
9360 PRINT"YOU HAVE FIRED UPON ";:IFSW=46,PRINT"VACANT SPACE.":RETURN
9370 GOSUB20000:IFRND(100)>97-(20-WE)OREU<80,PRINT" AND NEED MORE":PRINTP3$" TO DESTROY IT!":RETURN
9380 IFMS=0ANDRND(100)>97,PRINT" AND MISSED IT!":MS=1:RETURN
9390 PRINT", HIT IT, AND DESTROYED IT!":MS=0:WT=351
9400 'BLOW UP DEST ENT
9410 S1=0:GOSUB7500
9420 'DID WE JUST BLOW UP THE ENEMY BASE?
9430 IFSW=72,XH=-XH:GOTO860
9499 RETURN
9600 'SUB ABBS
9610 PRINT"E - ENTERPRISE              F - FERENGI SHIP"
9620 PRINT"H - HOSTILE ALIEN BASE      K - KLINGON SHIP"
9630 PRINT"B - FEDERATION STARBASE     R - ROMULAN SHIP"
9640 PRINT"S - SUPPLY PLANET           W - WORM HOLE"
9650 PRINT"C - "S9$"            * - STAR"
9660 PRINT". - VACANT SPACE/HAVE *NOT* BEEN TO THAT SECTOR BEFORE"
9699 PRINT"@ - HAVE BEEN TO THAT SECTOR BEFORE":RETURN
9900 'SUB PR.CURR.S
9905 'S STORED IN AN ARRAY, NUMBERED LIKE A CARTESIAN COORDINATE SYSTEM, DISPLAYED AS A CCS OR A GAME COORD SYS
9910 IFRD,FORI=1TO7:FORJ=1TO7:VM=(8-J)*64+I*3ELSEFORJ=1TO7:FORI=1TO7:VM=J*64+I*3
9920 VM=VM+15398:IFRD,POKEVM,S(I,J):NEXTJ,IELSEPOKEVM,S(J,8-I):NEXTI,J
9999 RETURN
10000 'SUB PR.CREDITS
10010 GOSUB 3700 : CE$ = STRING$( 43 , 45 ) : GOSUB 7900
10020 CU$="TRS-80 ADVANCED BASIC CONCEPT BY AL WALLACE":GOSUB6400
10050 CU$="ALL RIGHTS RESERVED BY GENE RODDENBERRY & OTHERS":GOSUB6400
10070 CU$="GW-BASIC VERSION BY AL WALLACE & NONNIE MOUSE":GOSUB6400
10090 CE$="AND THANKS TO SCOTT SOREL WITHOUT WHOM THESE PROGRAMS WOULD":GOSUB7900
10100 CU$="NOT HAVE BEEN POSSIBLE":GOSUB6400
10120 CU$="VERSION:  3.99922":GOSUB6400
10199 WT=1511:GOSUB31350:RETURN
10200 'SUB CODE.S
10210 A=4:B=4:S(4,4)=69:CN=GF:SY=70:GOSUB7600:CN=GW:SY=87:GOSUB7600:CN=GS:SY=42:GOSUB7600:CN=GB:SY=66:GOSUB7600:CN=GP:SY=83:GOSUB7600:CN=GR:SY=82:GOSUB7600:CN=GK:SY=75:GOSUB7600
10220 EV=GF+GR+GK:IFEV>0,CO$=R$
10230 IFX=XHANDY=YH,CN=1:SY=72:GOSUB7600
10299 RETURN
10300 'SUB YOU.MUST
10310 PRINT"TO WIN, WITHIN 99 STARDATES, YOU MUST FIND AND DESTROY THE      HOSTILE ALIEN BASE!  DO NOT RUN OUT OF ENERGY OR SUPPLIES, ";
10320 PRINT"AND  THE CREW OF 500 ACTIVE DUTY PERSONNEL MUST REMAIN ON ACTIVE DUTYWITH A MINIMUM OF 300 PERSONNEL."
10330 PRINT:PRINT"YOU MUST DO ALL THIS WHILE TRYING TO DESTROY:":PRINTUSING"##+ FERENGI, ##+ KLINGONS, ##+ ROMULANS.";FT,KT,RT
10399 PRINT"TO DOCK"WI$"A BASE, OR SUPPLY PLANET, MOVE SLOWLY OVER IT!":WT=2021:GOSUB31350:RETURN
10500 'SUB MAIN
10510 PRINT@730,"MAIN MENU":PRINT"NAVIGATION - - - 1     CHEAT - - - - - - - 5":PRINT"COMPUTER ....... 2     ABANDON SHIP ...... 6    SKIP TURN ... 0"
10599 PRINT"SHIELDS/CHAFF -  3     STATS - - - - - - - 7":PRINT"WEAPONS ........ 4     COORDINATE SYS .....8";:RETURN
10700 'SUB LR.SCAN
10705 'SECTORS STORED IN AN ARRAY, #ED LIKE A CARTESIAN COORD SYS, DISPLAYED AS A CCS OR A GAME COORD SYS
10710 GOSUB2900:GOSUB5800
10720 PRINT@384,;:CE$=PW$:GOSUB7900:LR=1:PRINT@963,"WORM HOLES - STARS - BASES - SUPPLY PLANETS + ENEMY VESSELS";
10725 IFRD,PRINT@641,"X-";:PRINT@704,"COLS";:PRINT@907,"Y-ROWS IN "CC$" - EXPRESSED AS X,Y";ELSEPRINT@641,"Y-";:PRINT@704,"ROWS";:PRINT@907,"X-COLUMNS IN "GC$" - EXPRESSED AS Y,X";
10730 IFRD,FORI=1TO7:FORJ=1TO7:GI=G(I,J)ELSEFORJ=1TO7:FORI=1TO7:GI=G(I,8-J)
10740 Q=1000000:F8=INT(GI/Q):G8=GI-F8*Q:GI=INT(G8/100):IFI=XHANDJ=YH,GI=GI+10
10750 G8=G8-INT(G8/100)*100:K8=INT(G8/10):R8=G8-K8*10:E8=F8+K8+R8
10760 IFRD,PR=(8-J)*64ELSEPR=J*64
10770 PRINT@PR+I*8+382,USING"####+#";GI,E8;
10780 IFRD,NEXTJ,IELSENEXTI,J
10790 PRINT@384,;:CE$=PK$:GOSUB7900:WT=91601:GOSUB2700:IFC6=0,PRINT@384,S0$;
10799 SD=SD-.5:WT=0:RETURN
11000 'SUB DOES.THE.ALIEN.BASE.EXIST?
11010 PRINT"THE ALIEN BASE ";:IFXH>0,PRINT"IS STILL OPERATING";ELSEPRINT"WAS BLOWN UP";
11020 IFOV,PRINT" IN SECTOR:  ";:Q=ABS(XH):Z=YH:GOSUB7300:PRINT:IFRD,PRINT"IN "CC$ELSEPRINT"IN "GC$
11099 RETURN
11200 'SUB STATS
11210 PRINT"STARDATE - - - - - - - - - - - - "USING"##.###";SD;:IFSD>88,PRINT" *"ELSEPRINT
11220 PRINT"SHIELDS ........................."SH"%";:IFSH<21,PRINT" *"ELSEPRINT
11230 PRINT"ENERGY REMAINING  - - - - - - -  ";E;:IFE=<5000,PRINT" *"ELSEPRINT
11240 PRINT"DAYS OF SUPPLIES REMAINING .......";SU;:IFSU=<11,PRINT" *"ELSEPRINT
11250 PRINT"CREW REMAINING ON ACTIVE DUTY - - ";USING"###";500-CA;:IFCA>170,PRINT" *"ELSEPRINT
11260 PRINT"CREW REPLENISHED .................";:PRINTUSING"###";RE:PRINT"CREW DEAD OR INJURED  - - - - - - ";USING"###";TC
11270 'FKR STATS
11280 GOSUB20200
11290 'DOES THE ALIEN BASE EXIST?
11299 GOSUB11000:WT=161:RETURN
11300 'SUB HOSTILES FIRING
11310 PRINT:PRINT"THE ENTERPRISE IS ";:IFEA>0,PRINTUSING"BEING FIRED   UPON BY # HOSTILE";EA;:IFEA=1,PRINTELSEPRINT"S"ELSEPRINT"NOT BEING     FIRED UPON"
11320 IFEA=0,WT=144ELSEGOSUB12000:WT=341
11399 RETURN
12000 'SUB SHAKE.SCR
12099 BS=40:LS=15:N=RND(3)+3:FORI=1TON:PRINTCHR$(23);:FORJ=0TOBS:NEXT:PRINTCHR$(28):FORQ=0TOLS:NEXTQ,I:ML=64:RETURN
14000 'SUB DRAW.ST
14010 GOSUB 3700 : IF CM < 5 THEN RO=1:GOSUB14400 ELSE PRINT "STAR TREK" : RETURN
14020 PRINTCHR$(188)STRING$(2,131)CHR$(140)"  "STRING$(2,131)CHR$(191)STRING$(2,131)"  ";
14030 PRINTCHR$(188)CHR$(131)CHR$(188)"    "CHR$(191)CHR$(131)CHR$(131)CHR$(188)"     ";
14040 PRINTSTRING$(2,131)CHR$(191)STRING$(2,131)" ";
14050 PRINTCHR$(191)CHR$(131)CHR$(131)CHR$(188)" ";
14060 PRINTCHR$(191)STRING$(3,131)"  "CHR$(191)"   "CHR$(154):RO=2:GOSUB14400
14070 PRINTSTRING$(3,131)CHR$(191)"    "CHR$(191)"   ";
14080 PRINTCHR$(191)STRING$(3,140)CHR$(191)"   "CHR$(191)CHR$(140)CHR$(166)CHR$(131);
14090 PRINT"       "CHR$(191)"   "CHR$(191)CHR$(140)CHR$(166)CHR$(131)" ";
14100 PRINTCHR$(191)CHR$(140)CHR$(140)"   "CHR$(191)CHR$(140)CHR$(172)CHR$(131)" ";:RO=3:GOSUB14400
14110 RO=3:GOSUB14400
14120 PRINTCHR$(131)CHR$(140)CHR$(140)CHR$(131);
14130 PRINT"    "CHR$(143)"   "CHR$(143)"   "CHR$(143)"   "CHR$(143);
14140 PRINT"  "CHR$(137)"       "CHR$(143)"   "CHR$(143)"  "CHR$(137);
14199 PRINT" "CHR$(143)STRING$(3,140)"  "CHR$(143)"  "CHR$(137):WT=131:GOSUB2700:RETURN
14400 'SUB DRAW.ST.GOTO.ROW
14499 PRINT@134+(RO-1)*64,;:RETURN
15000 'SUB CHEAT
15099 GOSUB3100:PRINT@320,"THE ENEMY STARBASE IS LOCATED":PRINT"AT:  ";:Q=XH:Z=YH:GOSUB7200:WT=151:RETURN
15200 'SUB SET.WE
15210 IFPB$=Y$,EM=2ELSEEM=10
15220 PRINT@512,S0$:PRINT@576,"POWER";:FORZ=1TOEM:PRINTUSING" ##.#";Z;:NEXT:PRINT:PRINT"LEVEL";:FORZ=1TOEM:FE=E*Z/100:PRINTUSING" ####";FE;:NEXT:PRINT
15230 PRINT:PRINTUSING"ENTER THE POWER LEVEL = 0-## (DEFAULT)";EM;:INPUTWE$
15240 IFWE$="0",WE=0:RETURN
15250 IFWE$="",WE=EMELSEWE=VAL(WE$)
15260 IFWE=0,15230
15270 IFWE>EM,PRINT"INVALID AMOUNT OF ENERGY":GOTO15230
15299 RETURN
18000 'SUB MAIN.SCR
18010 IFGK>0ORGR>0ORGF>0,CO$=R$
18020 IFTP=0,TP$=R$
18040 GOSUB3700:GOSUB2900:PRINT"AT COORDINATES ......";:IFRD,PRINTA","8-BELSEPRINTB","A
18050 PRINT"ENERGY LEVEL - - - -  "USING"#####";E:IFE<5000,CO$=R$:POKE15516,42
18060 PRINT"SHIELDS ARE AT ........"USING"###%  ";SH:IFSH<50,POKE15580,42
18070 PRINT"COMPUTER SYSTEMS  - - ";CS$:IFCS$=R$,POKE15644,42
18080 PRINT"WARP DRIVE SYSTEM ....";WD$:IFWD$=Y$,POKE15709,42
18090 IFWD$=R$,POKE15708,42
18100 PRINT"IMPULSE DRIVE - - - - ";ID$:IFID$=Y$,POKE15773,42
18110 IFID$=R$,POKE15772,42
18120 PRINT"PHASER BANK SYSTEM ...";PB$:IFPB$=R$,POKE15836,42
18130 IFPB$=Y$,POKE15837,42
18140 PRINT"TORPEDO SYSTEM  - - - "TP$:IFTP$=R$,POKE15900,42 
18150 PRINT"PHOTON TORPEDOES .....";
18160 IFTP=10,PRINT"10"
18170 IFTP<10,PRINTUSING"#";TP
18180 IFTP<4,POKE15964,42
18190 PRINT@549,"STARDATE  - - - - "USING"##.###";SD;:IFSD>88,POKE15907,42
18200 PRINT@613,"ALERT CONDITION ..."CO$:IFCO$=R$,POKE15971,42
18299 RETURN
20000 'SUB PR.WHAT.IT.IS.GIVEN.SW
20010 IFSW=42,PRINT"A STAR";
20020 IFSW=46,PRINT"VACANT SPACE";
20030 IFSW=66,PRINT"A FEDERATION STARBASE";
20040 IFSW=67,PRINT"SPACE CHAFF";
20050 IFSW=70,PRINT"A FERENGI SHIP";
20060 IFSW=72,PRINT"THE HOSTILE BASE";
20070 IFSW=75,PRINT"A KLINGON SHIP";
20080 IFSW=82,PRINT"A ROMULAN SHIP";
20090 IFSW=87,PRINT"A WORM HOLE";
20100 IFSW=83,PRINT"A SUPPLY PLANET";
20199 RETURN
20200 'SUB FKR.STATS
20210 PRINT"FERENGI CRAFT DESTROYED ...."FK" OR ";:PRINTUSING"###.#";FK/FT*100;:PRINTUSING"% OF TARGET: ##";FT;:IFFK<FT,PRINT" *"ELSEPRINT
20220 PRINT"KLINGON CRAFT DESTROYED - - "KK" OR ";:PRINTUSING"###.#";KK/KT*100;:PRINTUSING"% OF TARGET: ##";KT;:IFKK<KT,PRINT" *"ELSEPRINT
20230 PRINT"ROMULAN CRAFT DESTROYED ...."RK" OR ";:PRINTUSING"###.#";RK/RT*100;:PRINTUSING"% OF TARGET: ##";RT;:IFRK<RT,PRINT" *"ELSEPRINT
20240 IFSD>0,PRINT"CRAFT DESTROYED ...."FK+KK+RK" OR "(FK+KK+RK)/SD" KILL(S) PER STARDATE!"
20299 RETURN
21000 'SUB UPD.DES.ENT.STATS
21003 IFRD,Z=JELSEZ=8-J
21010 'STAR
21015 IFSW=42,G(X,Z)=G(X,Z)-10000
21020 'FEDERATION STARBASE
21025 IFSW=66,G(X,Z)=G(X,Z)-1000
21030 'SPACE CHAFF
21035 IFSW=67,SC=SC-1
21040 'FERENGI SHIP
21045 IFSW=70,G(X,Z)=G(X,Z)-1000000:GF=GF-1:FK=FK+1
21050 'HOSTILE BASE
21055 IFSW=72,XH=-XH
21060 'KLINGON SHIP
21065 IFSW=75,G(X,Z)=G(X,Z)-10:GK=GK-1:KK=KK+1
21070 'ROMULAN SHIP
21075 IFSW=82,G(X,Z)=G(X,Z)-1:GR=GR-1:KR=KR+1
21080 'SUPPLY PLANET
21085 IFSW=85,G(X,Z)=G(X,Z)-100
21099 EV=GK+GR+GF:RETURN
30000 'SUB GET.ZS
30010 PRINT"?";
30020 IFCM<5ORCM=6,Z$=INKEY$
30030 IFCM=7ORCM=8,GETZ$
30040 IFZ$="",30020ELSEZ=VAL(Z$)
30099 RETURN
31350 'SUB PRESS.ANY.KEY
31360 IFWT=0,RETURN
31370 IFCM<5,PRINT@960,;:CE$=PK$:GOSUB7900:GOSUB2700:GOSUB3700
31399 RETURN
31655 'ISO-8601
31656 '2025-5-17, RELEASE 3.99922
